FORM 4.0 (Jun 30 2012) 64-bits                   Run: Sat Aug  3 17:45:52 2013
    *   Title:  SMALL CHARGED SPHERE:  R(mu)*A(mu)
    *    File:  rdota.frm
    *  Author:  David N. Williams
    * License:  Creative Commons Attribution-Share Alike
    * Started:  November 8, 1987 (Schoonschip)
    *           July 8, 2012     (Form)
    * Revised:  July 8,9,28, 2012
    *
    * All parts of this program not in the public domain are:
    *
    *   Copyright (C) 1987, 2012 David N. Williams
    *
    * This work is licensed under the Creative Commons Attribution-
    * Share Alike 2.5 License.  To view a copy of this license, visit
    * http://creativecommons.org/licenses/by-sa/2.5/ or send a letter
    * to Creative Commons, 543 Howard Street, 5th Floor, San
    * Francisco, California, 94105, USA.
    *
    *   Input:  TAU1, TAU2, TAU3 from dtau.frm
    *  Output:  RdotA in rdota.sav
    *
    * We need RdotA through order eps^2 to get the leading
    * nonsingular term in the Lorentz force.
    
    
    *** DECLARATIONS
    
    off statistics;
    
    S eps;
    S c,snorm;
    I mu,nu,l,m;
    V u,a,j,n;
    T d1y,d2y,d3y,d1u,d2u,d1a;
    CF R,A;
    Load dtau.sav;
 TAU1 loaded
 TAU2 loaded
 TAU3 loaded
    
    
    *** MODULES
    
    L dtau = TAU1*eps + TAU2*eps^2;
    G RdotA = R(mu)*A(mu);
    
    Id R(mu?) = - d1y(mu,n)*eps - d2y(mu,n,n)*eps^2/2 
    
                    - d3y(mu,n,n,n)*eps^3/6
    
                - u(mu)*dtau - d1u(mu,n)*eps*dtau
    
                    - d2u(mu,n,n)*eps^2*dtau/2
    
                - a(mu)*dtau^2/2 - d1a(mu,n)*eps*dtau^2/2
    
                - j(mu)*dtau^3/6;
    
    Id eps^3 = 0;
    
    Id A(mu?) = a(mu) + d1a(mu,n)*eps
    
                + j(mu)*dtau;
    
    Id eps^3 = 0;
    
    Id u.u = c^2;
    Id u.a = 0;
    Id u.j = -a.a;
    
    Id d1u(u,l?) = 0;
    Id d1a(u,l?) = -d1u(a,l);
    Id d2u(u,l?,m?) = -d1u(nu,l)*d1u(nu,m);
    
    Sum mu;
    .sort
    
    b eps,snorm;
    print +s;
    .store

   dtau =

       + eps * (
          - d1y(u,n)*c^-2
          )

       + eps*snorm * (
          - c^-1
          )

       + eps^2*snorm^-1 * (
          + 1/2*d1y(u,n)*d1y(u,n)*d1y(a,n)*c^-5
          - d1y(u,n)*d1y(N1_?,n)*d1u(N1_?,n)*c^-3
          - 1/2*d1y(u,n)*d2y(u,n,n)*c^-3
          + 1/2*d1y(N1_?,n)*d2y(N1_?,n,n)*c^-1
          )

       + eps^2 * (
          + d1y(u,n)*d1y(a,n)*c^-4
          - d1y(N1_?,n)*d1u(N1_?,n)*c^-2
          - 1/2*d2y(u,n,n)*c^-2
          )

       + eps^2*snorm * (
          + 1/2*d1y(a,n)*c^-3
          );

   RdotA =

       + eps * (
          - d1y(a,n)
          )

       + eps^2 * (
          + 1/2*d1y(u,n)*d1y(u,n)*a.a*c^-4
          + d1y(u,n)*d1y(j,n)*c^-2
          - d1y(N1_?,n)*d1a(N1_?,n)
          - 1/2*d2y(a,n,n)
          )

       + eps^2*snorm * (
          + d1y(u,n)*a.a*c^-3
          + d1y(j,n)*c^-1
          )

       + eps^2*snorm^2 * (
          + 1/2*a.a*c^-2
          );

    
    save rdota.sav RdotA;
    .end
  0.01 sec out of 0.01 sec