FORM 4.0 (Jun 30 2012) 64-bits                   Run: Mon Feb  4 11:47:30 2013
    *   Title:  POINT CHARGE:
    *           retarded and advanced Poynting vector
    *           for acceleration fields
    *    File:  poynting.frm
    *  Author:  David N. Williams
    * License:  Creative Commons Attribution-Share Alike
    * Started:  August 24, 2012
    * Revised:  August 24-26,28, 2012
    *
    * All parts of this program not in the public domain are:
    *
    *	Copyright (C) 2012 David N. Williams
    *
    * This work is licensed under the Creative Commons Attribution-
    * Share Alike 2.5 License.	To view a copy of this license, visit
    * http://creativecommons.org/licenses/by-sa/2.5/ or send a letter
    * to Creative Commons, 543 Howard Street, 5th Floor, San
    * Francisco, California, 94105, USA.
    *
    *	Input:	none
    *  Output:	log file
    
    #if 0
    This program computes the Poynting vector for the retarded and
    advanced E and B acceleration fields for a point charge.  The
    results are well-known.
    
    We use Gaussian units.  All vectors are ret/adv (short for
    retarded/advanced), the Lorentz metric is (+---), and four-
    vector indices have the values 0,12,3.
    
    NOTATION
    
      c          speed of light
      R          source to field light cone displacement four-vector
      u          source four-velocity 
      a          source four-acceleration
      R0, etc.   time components
      E,B        three-vector electric, magnetic fields
      S          Poynting vector, c/4pi E x B
      R.u, etc.  three-vector dot products
      RDu ,etc.  four-vector dot products
    
    RESULTS
    
      [E.E] = [B.B],  [E.B] = 0
    
      S(i) = R(i)*R0*[c/4pi][|RDu|]^-6 * ( - RDu^2*aDa - c^2*RDa^2 )
    
    Note that sgn(R0) = sgn(RDu) is +/- for ret/adv.  That the last
    factor in S(i) is Lorentz invariant is not surprising because in
    the covariant energy-momentum tensor
    
      T^{i0} = T^{0i} = 1/4pi (E x B)^i
    
    must be composed of three-vector and time components multiplied
    by Lorentz scalars.
    
    In the local ret/adv rest frame, u = {c,0),	 a = (0,a'), and
    R = (R0',R'), so
    
      - (RDu)^2 aDa - c^2 (RDa)^2
    
    	  = c^2 (R0'^2 a'.a' - (R'.a')^2 ) >= 0 ,
    
    since |R0'| = |R'|.	 Hence the radiation is being emitted/
    absorbed when the fields are ret/adv, corresponding to sgn(R0).
    #endif
    
    *** DEBUGGING
    
    #procedure try
    Print +s;
    .end
    #endprocedure
    
    *** DECLARATIONS
    
    off statistics;
    
    Dimension 3;
    S c,[c/4pi],R0,u0,a0,RDu,RDa,uDu,aDa,[|RDu|];
    I i,j,k,m,n;
    V R,u,a;
    * dummies
    V v1,v2;
    .global
    
    *** MODULES
    
    G Ef(i)  = RDa*( R0*u(i) - u0*R(i) ) - RDu*( R0*a(i) - a0*R(i) );
    G Bf(i)  = RDa*e_(i,j,k)*R(j)*u(k)   - RDu*e_(i,j,k)*R(j)*a(k);
    G En(i) = -c^2*( R0*u(i) -u0*R(i) );
    G Bn(i) = -c^2*e_(i,j,k)*R(j)*u(k);
    Multiply [|RDu|]^-3;
    .store
    
    G [Ef.Ef] = Ef(i)*Ef(i);
    G [Bf.Bf] = Bf(i)*Bf(i);
    G [Ef.Bf] = Ef(i)*Bf(i);
    G [Ef.Ef-Bf.Bf] = [Ef.Ef] - [Bf.Bf];
    G [En.En] = En(i)*En(i);
    G [Bn.Bn] = Bn(i)*Bn(i);
    G [En.Bn] = En(i)*Bn(i);
    G [En.En-Bn.Bn] = [En.En] - [Bn.Bn];
    Contract;
    
    Id RDu = R0*u0 - R.u;
    Id RDa = R0*a0 - R.a;
    Id u.a = u0*a0;
    Id R.R = R0*R0;
    Id u.u = -c^2 + u0*u0;
    .sort
    
    S [RiR0],[Riu0],[uiR0];
    
    G Sf(i) = [c/4pi]*e_(i,j,k)*Ef(j)*Bf(k);
    G Sn(i) = [c/4pi]*e_(i,j,k)*En(j)*Bn(k);
    Contract;
    
    Id u.a = u0*a0;
    Id R.R = R0*R0;
    Id u.u = -c^2 + u0*u0;
    Id a.a = -aDa + a0*a0;
    Id R.u = -RDu + R0*u0;
    
    Id RDa   = R0*a0 - R.a;
    Id R.a^2 = RDa^2 - R0^2*a0^2 + 2*R.a*R0*a0;
    
    Id R(i)*R0 = [RiR0];
    Id R(i)*u0 = [Riu0];
    Id u(i)*R0 = [uiR0];
    .sort
    
    B [RiR0],[Riu0],[uiR0],[c/4pi],[|RDu|];
    Print;
    .end

   [Ef.Ef] =
       + [|RDu|]^-6 * (  - R0^2*RDu^2*aDa - c^2*R0^2*RDa^2 );

   [Bf.Bf] =
       + [|RDu|]^-6 * (  - R0^2*RDu^2*aDa - c^2*R0^2*RDa^2 );

   [Ef.Bf] = 0;

   [Ef.Ef-Bf.Bf] = 0;

   [En.En] =
       + [|RDu|]^-6 * ( 2*c^4*R0*u0*RDu - c^6*R0^2 );

   [Bn.Bn] =
       + [|RDu|]^-6 * (  - c^4*RDu^2 + 2*c^4*R0*u0*RDu - c^6*R0^2 );

   [En.Bn] = 0;

   [En.En-Bn.Bn] =
       + [|RDu|]^-6 * ( c^4*RDu^2 );

   Sf(i) =
       + [c/4pi]*[|RDu|]^-6*[RiR0] * (  - RDu^2*aDa - c^2*RDa^2 );

   Sn(i) =
       + [c/4pi]*[|RDu|]^-6*[uiR0] * ( c^4*RDu )

       + [c/4pi]*[|RDu|]^-6*[Riu0] * ( c^4*RDu )

       + [c/4pi]*[|RDu|]^-6*[RiR0] * (  - c^6 );

  0.00 sec out of 0.00 sec