libname sasdata2 "e:\sasdata2";

proc sort data=sasdata2.autism_socialization;
  by newinit cohort ;
run;

/*Question 1*/
/*Create a Count variable called VISIT*/

data autism_count;
     set sasdata2.autism_socialization;
	 by newinit cohort;

	 retain VISIT 0;

	 if first.newinit then visit=0;

	 visit=visit+1;
run;

proc print data=autism_count(obs=25);
  var newinit cohort visit;
  format cohort 2.0;
run;

/*Question 2*/
/*Output only the last observation for a child*/

data autism_lastvisit;
     set sasdata2.autism_socialization;
	 by newinit cohort;

	 retain VISIT 0;

	 if first.newinit then visit=0;

	 visit=visit+1;

	 keep newinit cohort visit;
	 if last.newinit then output;
run;

proc print data=autism_lastvisit(obs=25);
  var newinit cohort visit;
  format cohort 2.0;
run;

/*Question 3*/
/*Use Proc Means to create summary statistics for a child using Proc Means*/

proc means data=sasdata2.autism_socialization noprint;
  by newinit;
  output out=autism_childdata(drop=_type_ rename=(_freq_=numvisits))
         mean(vsae) = vsae_mean
		 min(vsae)  = vsae_min
		 max(vsae)  = vsae_max
		 n(vsae)    = vsae_n
		 mean(ageauto)=age_mean;
  *id sex ...; /*Use syntax like this to save variables that don't change*/
run;

proc print data=autism_childdata(obs=10);
run;

proc means data=autism_childdata;
run;