/***********************************************************
 THIS COMMAND FILE READS IN RAW DATA FROM THE AFIFI STUDY
 AND CONTAINS SAS COMMANDS FOR SOME BASIC STATISTICAL 
 ANALYSES.

 FILENAME: STATISTICS.SAS
*************************************************************/
OPTIONS FORMCHAR="|----|+|---+=|-/\<>*";
options pageno=1 nodate;
title;
DATA AFIFI;
    INFILE "AFIFI.DAT";
    INPUT
    #1 IDNUM 1-4 AGE 5-8 SEX 13-15 SURVIVE 16 SHOKTYPE 17-20 SBP1 21-24
       MAP1 25-28 HEART1 29-32 CARDIAC1 45-48 2 URINE1 57-60 HGB1 69-72 1
    #2 SBP2 21-24 MAP2 25-28 HEART2 29-32 CARDIAC2 45-48 2 URINE2 57-60
       HGB2 69-72 1;
    LABEL SHOCK="Shock type"
       SBP1="Systolic BP at time 1"
       SBP2="Systolic BP at time 2"
       MAP1="Mean arterial pressure at time 1"
       MAP2="Mean arterial pressure at time 2"
       HEART1="Heart rate at time 1"
       HEART2="Heart rate at time 2"
       CARDIAC1="Cardiac index at time 1"
       CARDIAC2="Cardiac index at time 2"
       URINE1="Urinary output at time 1"
       URINE2="Urinary output at time 2"
       HGB1="Hemoglobin at time 1"
       HGB2="Hemoglobin at time 2" ;

    IF SHOKTYPE=2 THEN SHOCK=1;
    IF SHOKTYPE IN (3,4,5,6,7) THEN SHOCK=2;
    IF SURVIVE=1 THEN DIED=0;
    IF SURVIVE=3 THEN DIED=1;
    SBPDIFF=SBP2-SBP1;
    LABEL SHOCK="Binary Shock"; 
RUN;
PROC FORMAT;
    VALUE SEXFMT   1="1: Male" 2="2: Female" ;
    VALUE SURVFMT  1="1: Lived" 3="3: Died" ;
    VALUE SHKTYFMT 2="2: Non-Shock" 
	              3="3: Hypovolemic"
			   4="4: Cardiogenic"
			   5="5: Bacterial"
			   6="6: Neurogenic"
			   7="7: Other";
    VALUE SHOCKFMT 1="1: No shock" 2="2: Shock" ;
RUN;

PROC DATASETS LIB=WORK;
    MODIFY AFIFI;
    FORMAT SEX SEXFMT. SURVIVE SURVFMT. 
	       SHOKTYPE SHKTYFMT. SHOCK SHOCKFMT.;
RUN;

PROC CONTENTS DATA=AFIFI VARNUM;
RUN;

OPTIONS _LAST_=AFIFI;

TITLE "DESCRIPTIVE STATISTICS";
PROC MEANS;
RUN;

TITLE "FREQUENCY TABLES FOR SELECTED VARIABLES" ; 
PROC FREQ;
    TABLES SEX SURVIVE SEX SHOKTYPE SHOCK ;
RUN;

TITLE "CROSS TABULATIONS FOR SURVIVAL AND SHOCK TYPE" ; 
PROC FREQ;
    TABLES SHOCK*SURVIVE/CHISQ EXPECTED RELRISK;
RUN;

TITLE "HISTOGRAMS" ; 
PROC UNIVARIATE;
    ID IDNUM;
    VAR SBP1 URINE1 ;
    HISTOGRAM;
RUN;

TITLE "INDEPENDENT SAMPLES T-TEST FOR SELECTED VARIABLES";RUN;
PROC TTEST;
    CLASS SURVIVE ;
    VAR SBP1 HEART1 CARDIAC1 MAP1;
RUN;

TITLE "PAIRED T-TEST FOR SBP1 VS. SBP2";
PROC TTEST;
    PAIRED SBP2*SBP1;
RUN;


PROC SORT;
    BY SURVIVE ; 
RUN;

TITLE "PAIRED T-TEST FOR SBP1 VS. SBP2";
TITLE2 "SEPARATELY FOR THOSE WHO SURVIVED AND THOSE WHO DIED"; 
PROC TTEST;
    BY SURVIVE;
    PAIRED SBP2*SBP1;
RUN;

TITLE "CORRELATIONS" ;
PROC CORR NOMISS;
    VAR SBP2 CARDIAC1 HEART1 HGB1 MAP1 ;
RUN;

ODS GRAPHICS ON;
TITLE "REGRESSION ANALYSIS WITH DIAGNOSTIC PLOTS";
TITLE2 "AND ANALYSIS OF RESIDUALS"; 
PROC REG DATA=AFIFI;
    MODEL SBP2= CARDIAC1 HEART1 HGB1 URINE1 MAP1 / PARTIAL;
    OUTPUT OUT=REGDAT P=PREDICT R=RESID;
RUN;QUIT;
ODS GRAPHICS OFF;

TITLE "CHECK NORMALITY OF RESIDUALS";
PROC UNIVARIATE;
    VAR RESID;
    HISTOGRAM;
    QQPLOT / NORMAL(MU=EST SIGMA=EST);
RUN;

TITLE "ONEWAY ANALYSIS OF VARIANCE";
TITLE2 "WITH TUKEY MULTIPLE COMPARISON METHOD";
PROC GLM;
    CLASS SHOKTYPE;
    MODEL SBP1=SHOKTYPE;
    LSMEANS SHOKTYPE/ ADJUST=TUKEY ;
RUN;QUIT;

TITLE "LOGISTIC REGRESSION";
PROC LOGISTIC DESCENDING;
   CLASS SHOKTYPE / PARAM=REF REF=FIRST;
   MODEL DIED = SHOKTYPE SBP1 CARDIAC1/ RSQUARE LACKFIT;
   UNITS SBP1=1 10; 
RUN;