OPTIONS FORMCHAR="|----|+|---+=|-/\<>*";
title;
libname sasdata2 "C:\Users\kwelch\Desktop\sasdata2";

/*Statistical Analyses*/
/*Independent Samples t-test*/
proc ttest data=sasdata2.employee;
  class gender;
  var salary;
run;
proc univariate data=sasdata2.employee;
  var salary;
  class gender;
  histogram;
run;
proc ttest data=sasdata2.employee dist=lognormal;
  class gender;
  var salary ;
run;
proc sort data=sasdata2.employee;
  by jobcat;
run;
proc ttest data=sasdata2.employee dist=lognormal;
  by jobcat;
  class gender;
  var salary;
run;

/*Correlation*/
proc corr data=sasdata2.employee;
  var salary salbegin educ;
run;

/*Linear Regression*/

proc reg data=sasdata2.employee;
  model salary = salbegin educ jobdum2 jobdum3 prevexp female;
  output out=regdat p=predict r=resid rstudent=rstudent;
run; quit;
proc univariate data=regdat;
  var rstudent;
  histogram / normal;
  qqplot / normal(mu=est sigma=est);
run;

data temp;
  set sasdata2.employee;
  logsalary = log(salary);
run;
proc reg data=temp;
  model logsalary = salbegin educ jobdum2 jobdum3 prevexp female;
  output out=regdat2 p=predict r=resid rstudent=rstudent;
run; quit;
proc univariate data=regdat2;
  var rstudent;
  histogram / normal;
  qqplot / normal(mu=est sigma=est);
run;


/*Chi-square test of independence*/
proc freq data=sasdata2.employee;
   tables gender*jobcat / chisq;
run;

title;
proc freq data=sasdata2.employee;
   tables gender*jobcat / chisq;
   exact fisher / mc seed=0;
run;