/*************************************
 This command file shows how to create
 permanent SAS datasets

 filename: saveperm.sas
**************************************/
OPTIONS FORMCHAR="|----|+|---+=|-/\<>*";
options pageno=1;
title;

/*Create a permanent SAS dataset
  using a data step*/

libname sasdata2 V9 "C:\Users\kwelch\Desktop\sasdata2";

data sasdata2.pulse;
   infile "pulse.dat";
   input pulse1 pulse2 ran smokes sex height weight activity;
run;


/*Use Proc Import to create a permanent dataset*/

title;
PROC IMPORT OUT= SASDATA2.PULSE 
 DATAFILE= "C:\Users\kwelch\Desktop\labdata\PULSE.XLS" 
 DBMS=EXCEL REPLACE;
     SHEET="pulse$"; 
     GETNAMES=YES;
     MIXED=NO;
     SCANTEXT=YES;
     USEDATE=YES;
     SCANTIME=YES;
RUN;

/*Create a permanent dataset
  as output from a procedure*/

proc reg data=sasdata2.pulse;
  model pulse2 = pulse1 ;
  output out = sasdata2.resids p=predict r=resid rstudent=rstudent;
run;
quit;

proc univariate data=sasdata2.resids;
  var resid;
  histogram;
  qqplot / normal (mu=est sigma=est);
run;

/*Use a permanent SAS dataset
  in later runs of SAS*/
libname sasdata2 V9 "C:\Users\kwelch\Desktop\sasdata2";
proc means data=sasdata2.pulse;
run;
proc freq data=sasdata2.pulse;
   tables ran smokes;
run;

/*Delete a permanent SAS dataset*/

proc datasets library=sasdata2;
  delete pulse;
  delete resids;
run; 
quit;