/*****************************************************
  THIS COMMAND FILE SHOWS HOW TO CREATE PERMANENT
  SAS DATA SETS 

  FILENAME:  SAVEPERM.SAS
*******************************************************/
OPTIONS PAGENO=1;
TITLE;
OPTIONS FORMCHAR="|----|+|---+=|-/\<>*";

/*CREATING A PERMANENT SAS DATA SET FROM RAW DATA*/

libname sasdata2 V9 "c:\temp\sasdata2";

data sasdata2.pulse;
   infile "pulse.dat";
   input pulse1 pulse2 ran smokes sex height weight activity;
   pulsedif  = pulse2 - pulse1;
   htm       = (height * 2.54)/100;
   wtkg      = weight * .39;
   bmi       = wtkg / htm**2; 
run;

/*RUNNING PROCEDURES USING THE PERMANENT DATA SET*/

title "SASDATA2.PULSE";
proc means;
run;

proc means data=sasdata2.pulse;
run;

/*THE LIBNAME CAN BE SET UP USING THE SAS LIBRARY WINDOW*/

proc means;
run;
proc freq;
   tables ran smokes;
run;

proc means data=sasdata2.pulse;
run;
proc freq data=sasdata2.pulse;
   tables sex ran smokes; 
run;

/*SAVE A PERMANENT SAS DATA SET USING PROC IMPORT*/

PROC IMPORT OUT= SASDATA2.PULSE 
            DATAFILE= "PULSE.XLS" 
            DBMS=EXCEL REPLACE;
     SHEET="pulse$"; 
     GETNAMES=YES;
     MIXED=NO;
     SCANTEXT=YES;
     USEDATE=YES;
     SCANTIME=YES;
RUN;

/*CREATE A PERMANENT DATA SET
   AS OUTPUT FROM A SAS PROCEDURE*/

proc reg data=sasdata2.pulse;
  model pulse2 = pulse1 ran;
  output out = sasdata2.resids p=predict r=resid rstudent=rstudent;
run;
quit;

/*USE THE SAVED DATA TO CHECK RESIDUALS*/
proc univariate data=sasdata2.resids;
  var resid;
  histogram;
  qqplot / normal (mu=est sigma=est);
run;

/*Use a Permanent SAS Data Set in Later Runs of SAS*/

libname sasdata2 V9 "c:\temp\sasdata2";
proc means data=sasdata2.pulse;
run;
proc freq data=sasdata2.pulse;
   tables ran smokes;
run;

/*DELETE PERMANENT SAS DATA SETS*/

libname sasdata2 V9 "c:\temp\sasdata2";
proc datasets library=sasdata2;
  delete pulse;
  delete resids;
run; 
quit;