* ******************************************************************
*  SPSS EXAMPLE 3: 
*  MULTIPLE LINEAR REGRESSION AND DIAGNOSTICS
* *****************************************************************.
GET FILE="d:\510\2006\werner.sav".

*-------------------------------------------------------------------------COMPUTE A NEW VARIABLE.
COMPUTE WTALB = WEIGHT + ALB.
EXECUTE.

*-------------------------------------------------------------------------------DESCRIPTIVES.
DESCRIPTIVES
  VARIABLES=chol age calcium acid alb weight wtalb
  /STATISTICS=MEAN STDDEV MIN MAX .

*---------------------------------------------------------------LISTWISE MISSING CORRELATIONS.
CORRELATIONS
  /VARIABLES=CHOL AGE CALCIUM ACID ALB WEIGHT WTALB
  /PRINT=TWOTAIL NOSIG
  /STATISTICS DESCRIPTIVES
  /MISSING=LISTWISE .


*---------------------------------------------------------------PAIRWISE MISSING CORRELATIONS.
CORRELATIONS
  /VARIABLES=CHOL AGE CALCIUM ACID ALB WEIGHT WTALB
  /PRINT=TWOTAIL NOSIG
  /STATISTICS DESCRIPTIVES
  /MISSING=PAIRWISE .

*-------------------------------------------------------------------------------SCATTER PLOT MATRIX.
GRAPH
  /SCATTERPLOT(MATRIX)=CHOL AGE CALCIUM ACID ALB WEIGHT WTALB
  /MISSING=LISTWISE .



*------------------------------------------------------MULTIPLE REGRESSION CHECK COLLINEARITY.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT CHOL
  /METHOD=ENTER AGE CALCIUM ACID ALB WEIGHT
  /SCATTERPLOT=(*SDRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID)
  /SAVE PRED COOK RESID SDRESID DFFIT .

*-------------------------------------MULTIPLE REGRESSION DEFINITE COLLINEARITY PROBLEM.
*-------------------------------------NOTE: SPSS REFUSES TO INCLUDE WEIGHT IN THE MODEL.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT CHOL
  /METHOD=ENTER AGE CALCIUM ACID ALB WEIGHT WTALB.


*--------------------------------------------------------------STEPWISE REGRESSION.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA CHANGE
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT CHOL
  /METHOD=STEPWISE AGE CALCIUM ACID ALB WEIGHT .

*--------------------------------------------------------------BACKWARD SELECTION METHOD.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA CHANGE
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT CHOL
  /METHOD=BACKWARD AGE CALCIUM ACID ALB WEIGHT .


*-------------------------------------------------------------ENTER VARIABLES IN BLOCKS.
REGRESSION
   /MISSING LISTWISE
  /STATISTICS COEFF OUTS  ANOVA CHANGE
  /CRITERIA=PIN(.05) POUT(.10) CIN(95)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER AGE WEIGHT   /METHOD=ENTER CALCIUM ACID /METHOD=ENTER ALB .