/***********************************************
 SAS EXAMPLE   -- FREQUENCY TABULATIONS
                  FOR MATCHED OR RELATED
                  CATEGORICAL VARIABLES.
                  MCNEMAR'S TEST OF SYMMETRY
                  COHEN'S KAPPA.
 FILENAME: matchfreq.sas
***********************************************/
OPTIONS NODATE PAGENO=1 FORMDLIM=" ";
TITLE;

/*********************McNemar's Test of Symmetry for Matched Samples*/
libname b510 "d:\510\2006\data";
data nopill;
  set b510.werner;
  if pill = 1;
  rename id = id1 
         age = age1
		 ht  = ht1
		 wt  = wt1
		 pill = pill1
		 chol = chol1
		 alb  = alb1
		 calc = calc1
		 uric = uric1
		 bmi  = bmi1
		 hibmi= hibmi1
		 agegroup = agegroup1
		 hiage    = hiage1
		 cholcat  = cholcat1
		 hichol   = hichol1
		 wtcat    = wtcat1;
		 drop rpill;
run;
 
data pill;
  set b510.werner;
  if pill = 2;
  rename id = id2 
         age = age2
		 ht  = ht2
		 wt  = wt2
		 pill = pill2
		 chol = chol2
		 alb  = alb2
		 calc = calc2
		 uric = uric2
		 bmi  = bmi2
		 hibmi= hibmi2
		 agegroup = agegroup2
		 hiage    = hiage2
		 cholcat  = cholcat2
		 hichol   = hichol2
		 wtcat    = wtcat2;
		 drop rpill;
run;

proc sort data=nopill;
  by pair;
run;
proc sort data=pill;
  by pair;
run;

data pairs;
  merge nopill pill;
  by pair;
run;
title "McNemar's Test for highchol and hibmi for pill and non-pill";
proc freq data=pairs;
  tables  hichol1*hichol2  hibmi1*hibmi2 / agree norow nocol;
run;


/******************Agreement, Using Cohen's Kappa*********************/

/* Agreement Study Example */

data SkinCondition;
      input derm1 $ derm2 $ count;
      datalines;
   terrible terrible 10
   terrible     poor 4
   terrible marginal 1
   terrible    clear 0
   poor     terrible 5
   poor         poor 10
   poor     marginal 12
   poor        clear 2
   marginal terrible 2
   marginal     poor 4
   marginal marginal 12
   marginal    clear 5
   clear    terrible 0
   clear        poor 2
   clear    marginal 6
   clear       clear 13
   ;

title "Agreement of two raters on skin condition";
proc freq data=SkinCondition order=data;
      weight count;
      tables derm1*derm2 / agree ;
      test kappa;
run;

*------------------------------COHEN'S KAPPA FOR INTER-RATER RELIABILITY;
DATA GRADERS;
 INPUT CANDIDATE EXAMINRA EXAMINRB;
 CARDS;
 1      1      2
 2      0      0
 3      0      0
 4      2      2
 5      0      0
 6      4      3
 7      0      0
 8      0      0
 9      0      0
10      2      3
11      1      2
12      2      3
13      0      1
14      4      3
15      4      3
16      1      2
17      0      2
18      1      2
19      2      3
20      0      0
21      2      3
22      4      4
23      0      0
24      0      0
25      4      3
26      0      2
27      1      2
28      3      4
29      2      3
;

TITLE "KAPPA AND WEIGHTED KAPPA: AGREEMENT FOR 2 RATERS";
TITLE2 "SCALE IS ORDINAL: WEIGHTED KAPPA IS APPROPRIATE";
TITLE3 "DATA FROM HAND ET AL";
PROC FREQ DATA=GRADERS;
  TABLES EXAMINRA * EXAMINRB / AGREE ;
  EXACT AGREE;
RUN;