IMPORT
  FILE='e:\510\2006\data\htwt.por'.

DESCRIPTIVES
  VARIABLES=age height weight
  /STATISTICS=MEAN STDDEV MIN MAX .

/*Create new variables and interactions*/
RECODE
  sex
  ('f'=1)  ('m'=0)  INTO  female .
EXECUTE .
value labels female (1) 1:Female (0) 0:Male.
Compute centage = age - 16.5.
Compute fem_age = female* age.
Compute fem_centage = female * centage.
EXECUTE.

/*Select Cases with Age < 19*/

USE ALL.
COMPUTE filter_$=(age < 19).
VARIABLE LABEL filter_$ 'age < 19 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE .

/*Scatter Plot of Height vs Age for Males and Females*/
GRAPH
  /SCATTERPLOT(BIVAR)= age WITH height BY sex
  /MISSING=LISTWISE .

/*ANCOVA with FEMALE, AGE, FEM_AGE interaction*/
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT height
  /METHOD=ENTER female age fem_age
  /SCATTERPLOT=(*SDRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) .

/*ANCOVA with FEMALE, CENTAGE, FEM_CENTAGE interaction (Centered Age)*/

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT height
  /METHOD=ENTER female centage fem_centage
  /SCATTERPLOT=(*SDRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) .

/*ANCOVA model using GLM*/

UNIANOVA
  height  BY sex  WITH centage
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /CRITERIA = ALPHA(.05)
  /DESIGN = sex centage centage*sex .

/*Separate regressions for males and for females*/
SORT CASES BY sex .
SPLIT FILE
  SEPARATE BY sex .

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT height
  /METHOD=ENTER centage
  /SCATTERPLOT=(*SDRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) .