*------------------------Syntax to read in Excel file .

GET DATA /TYPE=XLS
   /FILE='H:\Biostat 510\heartrate_2005.xls'
   /SHEET=name 'heartrate'
   /CELLRANGE=full
   /READNAMES=on .

*------------------------Recode RAN into RRAN .
RECODE Ran(0=2)  (1=1)  INTO  RRAN .
EXECUTE .
value labels RRAN (1) "RAN" (2) "Did not Run".

*--------------Compute BMI and get histogram using Explore.

COMPUTE wtkg = weight/2.2046 .
EXECUTE .
IF (ht_units="in") htm = height/39.37 .
EXECUTE .
IF (ht_units="cm") htm = height/100 .
EXECUTE .
COMPUTE  BMI = wtkg/htm**2.
EXECUTE .

EXAMINE
  VARIABLES=BMI
  /PLOT BOXPLOT HISTOGRAM
  /COMPARE GROUP
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*------------------------Alternative SPSS syntax for Descriptives and Histogram of BMI.
GRAPH
  /HISTOGRAM=BMI
  /TITLE= 'HISTOGRAM OF BMI'.

DESCRIPTIVES
  VARIABLES=BMI
  /STATISTICS=MEAN STDDEV MIN MAX .

*----------------------Automatic Recode to get Gender in to GENNUM.
AUTORECODE
  VARIABLES=Gender  /INTO GENNUM
  /PRINT.

*----------------------List cases and display dictionary.
list variables=all 
   /cases = from 1 to 10.
display dictionary.

DESCRIPTIVES
  VARIABLES=ID Monbir Daybir Yearbir Height Weight HRS_Exercise Distance Hrtrate1 Year Ran Hrtrate2 activity RRAN wtkg htm
  BMI GENNUM
  /STATISTICS=MEAN STDDEV MIN MAX .

*---------------------Histogram, Box-plot and descriptives for Hrtrate2 for each level of RRAN.
EXAMINE
  VARIABLES=Hrtrate2 BY RRAN
  /PLOT BOXPLOT HISTOGRAM
  /COMPARE GROUP
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
*---------------------Independent Samples t-test for Mean of Hrtrate2 for Ran and did not run.
T-TEST
  GROUPS = RRAN(1 2)
  /MISSING = ANALYSIS
  /VARIABLES = Hrtrate2
  /CRITERIA = CI(.95) .

*---------------------Paired t-test for Mean of Hrtrate1 vs. mean of Hrtrate2 for all students.
T-TEST
  PAIRS = Hrtrate1  WITH Hrtrate2 (PAIRED)
  /CRITERIA = CI(.95)
  /MISSING = ANALYSIS.

*---------------------Split the file by RRAN to get a separate analysis for each group.
SORT CASES BY RRAN .
SPLIT FILE
  SEPARATE BY RRAN .

*------------Recalculate Paired t-test for Mean of Hrtrate1 vs. mean of Hrtrate2 for those who
             ran and those who did not run.
T-TEST
  PAIRS = Hrtrate1  WITH Hrtrate2 (PAIRED)
  /CRITERIA = CI(.95)
  /MISSING = ANALYSIS.

SPLIT FILE
  OFF.
SAVE OUTFILE='C:\kwelch\510\2005\homework\heartrate.sav'
 /COMPRESSED.