/***********************************************
 SAS EXAMPLE 7 -- REGRESSION SELECTION METHODS
				  REGRESSION DIAGNOSTICS

 FILENAME: SELECT.SAS
************************************************/
OPTIONS NODATE FORMDLIM=" " PAGENO=1;
TITLE;
DATA WERNER;
   INFILE "c:\temp\labdata\werner2.dat";
   INPUT ID $ 1-4 AGE 5-8 HT 9-12 WT 13-16
           PILL 17-20  CHOL 21-24 ALB 25-28 1
           CALC 29-32 1 URIC 33-36 1;

   IF HT = 999 THEN HT = .;
   IF WT = 999 THEN WT = .;
   IF CHOL = 600 THEN CHOL = .;
   IF ALB = 99 THEN ALB = .;
   IF CALC = 99 THEN CALC = .;
   IF URIC = 99 THEN URIC = .;

  /*CREATE AGEGRP AND AGE INDICATOR DUMMY VARIABLES*/
   IF AGE NOT = . THEN DO;
      IF AGE < 25 THEN AGEGRP = 1;
      IF AGE >= 25 AND AGE < 32 THEN AGEGRP = 2;
      IF AGE >= 32 AND AGE < 42 THEN AGEGRP = 3;
      IF AGE >= 42              THEN AGEGRP = 4;
      AGEDUM1 = (AGEGRP = 1);  
      AGEDUM2 = (AGEGRP = 2);  
      AGEDUM3 = (AGEGRP = 3);  
      AGEDUM4 = (AGEGRP = 4);  
   END;
RUN;
*********************************************************************;
*REGRESSION SELECTION METHODS;
PROC REG DATA=WERNER;
     MODEL ALB=CALC WT CHOL AGE /SELECTION=STEPWISE DETAILS SLE=.05  SLS=.15;
     TITLE "STEPWISE REGRESSION ANALYSIS";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB=AGE CALC WT CHOL  /SELECTION=STEPWISE INCLUDE=1 
                                  DETAILS SLE=.05  SLS=.15;
     TITLE "STEPWISE REGRESSION ANALYSIS: FORCE AGE INTO MODEL";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB = {AGEDUM2 AGEDUM3 AGEDUM4} CALC WT CHOL /
                 SELECTION=STEPWISE INCLUDE=1 DETAILS SLE=.05 SLS=.15
                 GROUPNAMES="AGE DUMMIES" "CALCIUM" "WEIGHT" "CHOLESTEROL";
     TITLE "STEPWISE REGRESSION ANALYSIS: FORCE AGE DUMMIES INTO MODEL";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB=CALC WT CHOL AGE /SELECTION=BACKWARD DETAILS;
     TITLE "STEPWISE REGRESSION ANALYSIS";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB=CALC WT CHOL AGE URIC HT PILL /SELECTION=RSQUARE;
     TITLE "COMPARISON OF ALL POSSIBLE MODELS";
     TITLE2 "USING R-SQUARE AS THE SELECTION CRITERION";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB = CALC WT CHOL AGE URIC HT PILL/ 
                 SELECTION=RSQUARE START=1 STOP=4 BEST=5;
	 TITLE2 "USING RSQUARE AS SELECTION CRITERION";
	 RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB=CALC WT CHOL AGE/SELECTION=ADJRSQ;
     TITLE2 "USING ADJUSTED R-SQUARE AS CRITERION";
     RUN;QUIT;
PROC REG DATA=WERNER;
     MODEL ALB=CALC WT CHOL AGE/SELECTION=CP;
     TITLE2 "USING MALLOW'S CP AS SELECTION CRITERION";
     RUN;QUIT;

/*************REGRESSION DIAGNOSTICS******************/

PROC REG DATA=WERNER;
     MODEL ALB = CALC WT CHOL AGE / STB TOL VIF COLLIN R INFLUENCE;
     TITLE "REGRESSION DIAGNOSTICS";
RUN;QUIT;