* ******************************************************************
*  SPSS EXAMPLE 3: 
*  LINEAR REGRESSION AND DIAGNOSTICS
* *****************************************************************.
GET FILE="c:\temp\werner.sav".
COMPUTE bodymass = (weight/2.2026)/(height*.0254)**2 .
EXECUTE .
*-------------------------------------------------------------------------------DESCRIPTIVES.
DESCRIPTIVES
  VARIABLES=age height weight pill chol alb calcium acid logwt bodymass
  /STATISTICS=MEAN STDDEV MIN MAX .

*-------------------------------------------------------------------------------CORRELATIONS.
CORRELATIONS
  /VARIABLES=chol age acid alb bodymass calcium
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE .
CORRELATIONS
  /VARIABLES=chol age acid alb bodymass calcium
  /PRINT=TWOTAIL NOSIG
  /MISSING=LISTWISE .

*-------------------------------------------------------------------------------SCATTER PLOT.
GRAPH
  /SCATTERPLOT(BIVAR)=age  WITH chol 
  /MISSING=LISTWISE .

*-------------------------------------------------------------------------REGRESSION.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER age  .
*-------------------------------------------------------------SEVERAL PREDICTORS.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER  age acid alb bodymass calcium
  /SCATTERPLOT=(*ZRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID) 
  /SAVE PRED ZPRED SEPRED RESID ZRESID.

*--------------------------------------------------------------STEPWISE REGRESSION.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=STEPWISE age acid alb bodymass calcium pill  .

*-------------------------------------------------------------ENTER VARIABLES IN BLOCKS.
REGRESSION
   /MISSING LISTWISE
  /STATISTICS COEFF OUTS  ANOVA CHANGE
  /CRITERIA=PIN(.05) POUT(.10) CIN(95)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER age   /METHOD=ENTER acid calcium /METHOD=ENTER pill.


*---------------------------------------CALCULATE DUMMY VARIABLES .
RECODE
  age
  (Lowest thru 27=1)  (28 thru 39=2)  (40 thru Highest=3)  INTO  agegroup .
EXECUTE .
VALUE LABELS
          AGEGROUP (1) "YOUNG" (2) "MEDIUM" (3) "MATURE".

DO IF not(sysmis(AGEGROUP)).
COMPUTE agedum1=(agegroup=1).
COMPUTE agedum2=(agegroup=2).
COMPUTE agedum3=(agegroup=3).
END IF.
EXECUTE.

COMPUTE agesq = age*age.
EXECUTE.
COMPUTE centage = age-34.
EXECUTE.
COMPUTE centage2 = centage*centage.
EXECUTE.

*-------------------------------------------REGRESSION WITH SEVERAL DUMMY VARIABLES.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER agedum2 agedum3.


*----------------------------------------------SCATTER PLOT WITH QUADRATIC REGRESSION LINE.
GRAPH
  /SCATTERPLOT(BIVAR)=age  WITH chol 
  /MISSING=LISTWISE .

*-------------------------------------------REGRESSION WITH LINEAR AND QUADRATIC TERMS.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER age agesq.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT chol
  /METHOD=ENTER centage centage2.


*-------------------------------------------------------------SCATTER PLOT FOR PILL AND NOPILL.
GRAPH
  /SCATTERPLOT(BIVAR)=bodymass  WITH alb BY pill
  /MISSING=LISTWISE .


DO IF not(sysmis(PILL)).
COMPUTE pilldum=(pill=2).
END IF.
EXECUTE.

COMPUTE pillbmas = pilldum*bodymass.
EXECUTE .

COMPUTE centmas = bodymass-22.
EXECUTE.
COMPUTE pillcmas = pilldum*centmas.
EXECUTE.

*-----------------------------------------REGRESSION WITH DUMMY VARIABLE AND INTERACTION.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT alb
  /METHOD=ENTER pilldum bodymass pillbmas .

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.15)
  /NOORIGIN
  /DEPENDENT alb
  /METHOD=ENTER pilldum centmas pillcmas .