* ************************************************
* SPSS EXAMPLE 2--CROSSTABS
* File: crosstabs.sps
* *************************************************.

GET FILE='c:\temp\werner.sav'.
EXECUTE.
RECODE
  weight
  (Lowest thru 120=1) (121 thru 139=2) (140 thru Highest=3) into wtcat.
EXECUTE .
*-------------------------------NOTE: CODE RISK FACTOR SO 1=YES AND 2=NO.
*-------------------------------CODE OUTCOME AS 1=YES AND 2=NO.
*-------------------------------THIS WORKS BEST FOR RELATIVE RISK ESTIMATES.
RECODE
  age
  (40 thru Highest=1)   (Lowest thru 39=2)   INTO  hiage .
EXECUTE .
RECODE
  chol
  (241 thru Highest=1)  (Lowest thru 240=2)   INTO  hichol .
EXECUTE.
VALUE LABELS
           WTCAT (1) "LOW" (2) "MEDIUM" (3) "HIGH"
           /HIAGE  (2) "YOUNG" (1) "MATURE"
           /HICHOL (2) "LOW" (1) "HIGH".

FREQUENCIES
  VARIABLES=agegroup hiage hichol wtcat
  /ORDER  ANALYSIS .

*----------------------------------2 x 2 TABLE ESTIMATES OF RELATIVE RISK AND ODDS RATIO AS
                                    WELL AS CHI-SQUARE.
CROSSTABS
  /TABLES=hiage  BY hichol
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ CC PHI RISK
  /CELLS= COUNT EXPECTED ROW .

*-----------------------------------2 X 2 TABLE STRATIFIED BY PILL.
CROSSTABS
  /TABLES=hiage  BY hichol  BY pill
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ RISK CMH(1)
  /CELLS= COUNT EXPECTED ROW .

*----------------------------------3 X 2 TABLE.
CROSSTABS
  /TABLES=agegroup  BY hichol
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ CC PHI 
  /CELLS= COUNT ROW.

*-----------------------------------3 X 3 TABLE--ORDINAL VARIABLES.
CROSSTABS
  /TABLES=agegroup  BY wtcat
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ CORR GAMMA D BTAU CTAU
  /CELLS= COUNT ROW .


*-------------------------------------RUN ANALYSIS ON MATCHED DATA.

GET FILE="C:\TEMP\MATCHED.SAV".
EXECUTE.
RECODE
  acid1
  (lowest thru 5.5 =0)  (5.5 thru Highest=1) INTO  hiacid1 .
RECODE
  acid2
  (lowest thru 5.5=0)  (5.5 thru Highest=1)   INTO  hiacid2 .
EXECUTE.
VALUE LABELS hiacid1 hiacid2 (0) "LOW" (1) "HIGH".

CROSSTABS
  /TABLES=hiacid1  BY hiacid2
  /FORMAT= AVALUE TABLES
  /STATISTIC= MCNEMAR
  /CELLS= COUNT TOTAL .

DATA LIST FREE 
     /RATER1 RATER2 COUNT.
N OF CASES 9.
VALUE LABELS RATER1 RATER2 (1) "LOW" (2) "MED" (3) "HIGH".
BEGIN DATA.
1 1  20
1 2   3
1 3   1E-10
2 1   2
2 2  15
2 3   1
3 1   1
3 2   3
3 3  22
END DATA.
WEIGHT BY COUNT.

CROSSTABS
  /TABLES=rater1  BY rater2
  /FORMAT= AVALUE TABLES
  /STATISTIC=KAPPA
  /CELLS= COUNT TOTAL .