*-----------------------------------------------------------------------Question 1 - Read in Data.
data list records=2
  file = "c:\temp\labdata\afifi.dat"
  / id 1-4 age 5-8 height 9-12 sex 13-15
    survive 16 shoktype 17-20 sbp1 21-24 map1 25-28 heart1 29-32 
    dbp1 33-36 cvp1 37-40 (1) bsa1 41-44 (2) cardiac1 45-48 (2)
    apptime1 49-52 (1) circ1 53-56 (1) urine1 57-60 plasma1 61-64 (1) 
    redcell1 65-68 (1) hgb1 69-72 (1)  hct1 73-76 (1) time1 80
   / sbp2 21-24 map2 25-28 heart2 29-32 
     dbp2 33-36 cvp2 37-40 (1) bsa2 41-44 (2) cardiac2 45-48 (2)
     apptime2 49-52 (1) circ2 53-56 (1) urine2 57-60 plasma2 61-64 (1) 
     redcell2 65-68 (1) hgb2 69-72 (1)  hct2 73-76 (1) time2 80.
execute.
value labels sex 1 "Male" 2 "Female" /survive 1 "Lived" 3 "Died" /Shoktype 2 "Non-Shock"
   3 "Hypovolemic" 4 "Cardiogenic" 5 "Bacterial" 6 "Neurogenic" 7 "Other".
SAVE OUTFILE='C:\temp\afifi.sav'
  /COMPRESSED.

*-----------------------------------------------------------------------Question 1 - Descriptives.
DESCRIPTIVES
  VARIABLES=id age height sex survive shoktype sbp1 map1 heart1 dbp1 cvp1
  bsa1 cardiac1 apptime1 circ1 urine1 plasma1 redcell1 hgb1 hct1 time1 sbp2
  map2 heart2 dbp2 cvp2 bsa2 cardiac2 apptime2 circ2 urine2 plasma2 redcell2
  hgb2 hct2 time2
  /STATISTICS=MEAN STDDEV MIN MAX .

*------------------------------------------------------------------------Question 1 - Frequencies.
FREQUENCIES
  VARIABLES=sex survive shoktype
  /ORDER=  ANALYSIS .

*-----------------------------------------------------------------------Question 2 - Crosstabs.
CROSSTABS
  /TABLES=shoktype  BY survive
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ
  /CELLS= COUNT  ROW .

*-----------------------------------------------------------------------Question 3  - Recode New Variables.
RECODE
  shoktype
  (2=2)  (ELSE=1)  INTO  shock .
EXECUTE .
value labels shock 1 "Shock" 2 "No Shock".
RECODE
  survive
  (3=1)  (1=2)  INTO  died .
EXECUTE .
value labels died 1 "Died" 2 "Lived".
RECODE
  urine1
  (0=1)  (ELSE=2)  INTO  ur1 .
EXECUTE .
RECODE
  urine2
  (0=1)  (ELSE=2)  INTO  ur2 .
EXECUTE .
value labels ur1 ur2 1 "No Urinary Output" 2 "Some Urinary Output".
*-----------------------------------------------------------------------------------------Find Levels of SBP1 for Cutpoints.
EXAMINE
  VARIABLES=sbp1
  /PLOT NONE
  /PERCENTILES(5,10,25,50,75,90,95) HAVERAGE
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
 RECODE
  sbp1
  (0 thru 83=1)  (84 thru 103=2)  (104 thru 131=3)  (132 thru Highest=4)
  INTO  sbp1grp .
EXECUTE .

RECODE
  shoktype
  (2=0)  (ELSE=1)  INTO  shockdum .
EXECUTE .
RECODE
  survive
  (1=0)  (3=1)  INTO  dieddum .
EXECUTE .
*-----------------------------------------------------------------------------------------Find Levels of BSA1 for Cutpoints.
EXAMINE
  VARIABLES=bsa1
  /PLOT NONE
  /PERCENTILES(5,10,25,50,75,90,95) HAVERAGE
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
RECODE
  bsa1
  (Lowest thru 1.55=1)  (ELSE=0)  INTO  bsadum .
EXECUTE .

*-----------------------------------------------------------------------Question 3  - Frequencies of New Variables.
FREQUENCIES
  VARIABLES=shock died ur1 ur2 sbp1grp bsadum shockdum dieddum
  /ORDER=  ANALYSIS.

*-----------------------------------------------------------------------Question 4  - Crosstab.
CROSSTABS
  /TABLES=shock  BY died
  /FORMAT= AVALUE TABLES
  /STATISTIC=RISK
  /CELLS= COUNT ROW .

*----------------------------------------------------------------Question 4 - Calculate Odds Ratio For Each Level of Ur1.
CROSSTABS
  /TABLES=shock  BY died  BY ur1
  /FORMAT= AVALUE TABLES
  /STATISTIC=RISK CMH(1)
  /CELLS= COUNT ROW .

*----------------------------------------------------------------Question 5 - McNemar's Test for Related Categorical Variables.
CROSSTABS
  /TABLES=ur1  BY ur2
  /FORMAT= AVALUE TABLES
  /STATISTIC=MCNEMAR
  /CELLS= COUNT TOTAL .

*----------------------------------------------------------------Question 5 - Split File by Survive and Redo Crosstab.
SORT CASES BY survive .
SPLIT FILE
  SEPARATE BY survive .
CROSSTABS
  /TABLES=ur1  BY ur2
  /FORMAT= AVALUE TABLES
  /STATISTIC=MCNEMAR
  /CELLS= COUNT TOTAL .

*----------------------------------------------------------------Question 5 - Remember to Turn Split File Off.
SPLIT FILE
  OFF.


*-------------------------------------------------------------------Question 6 - Compute a New Variable and Check its distribution.
COMPUTE lnurine1 = ln(urine1+1) .
EXECUTE .

EXAMINE
  VARIABLES=lnurine1
  /PLOT BOXPLOT STEMLEAF
  /COMPARE GROUP
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*----------------------------------------------------Question 7 Regression Analysis.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT sbp2
  /METHOD=ENTER shockdum map1 heart1 cardiac1 bsa1 plasma1 urine1
  /SCATTERPLOT=(*ZRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID)
  /SAVE PRED RESID .

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT sbp2
  /METHOD=STEPWISE shockdum map1 heart1 cardiac1 bsa1 plasma1 urine1
  /SCATTERPLOT=(*ZRESID ,*ZPRED )
  /RESIDUALS HIST(ZRESID) NORM(ZRESID)
  /SAVE PRED RESID .

*----------------------------------------------------Question 8 - Logistic Regression.

LOGISTIC REGRESSION VAR=dieddum
  /METHOD=ENTER shoktype
  /CONTRAST (shoktype)=Indicator(1)
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

LOGISTIC REGRESSION VAR=dieddum
  /METHOD=ENTER shoktype sbp1 bsa1
  /CONTRAST (shoktype)=Indicator(1)
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

*----------------------------------------------------Question 9 - Oneway Anova.
ONEWAY
  sbp2 BY shoktype
  /STATISTICS DESCRIPTIVES
  /MISSING ANALYSIS
  /POSTHOC = TUKEY ALPHA(.05).

ONEWAY
  sbp2 BY sbp1grp
  /POLYNOMIAL= 1
  /STATISTICS DESCRIPTIVES
  /PLOT MEANS
  /MISSING ANALYSIS
  /POSTHOC = TUKEY ALPHA(.05).

*----------------------------------------------------Question 9 - Get Residuals--This needs to be done with GLM.
UNIANOVA
  sbp2  BY sbp1grp
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /SAVE = PRED RESID
  /CRITERIA = ALPHA(.05)
  /DESIGN = sbp1grp .

*--------------------------------------------------Question 9 - Check Residuals.
EXAMINE
  VARIABLES=res_1
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUP
  /STATISTICS NONE
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.


*---------------------------------------------------Question 10 - Twoway Anova.

UNIANOVA
  sbp2  BY sbp1grp bsadum
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /SAVE = PRED RESID
  /PLOT = PROFILE( sbp1grp*bsadum )
  /EMMEANS = TABLES(sbp1grp)
  /EMMEANS = TABLES(bsadum)
  /EMMEANS = TABLES(sbp1grp*bsadum)
  /PRINT = DESCRIPTIVE
  /CRITERIA = ALPHA(.05)
  /DESIGN = sbp1grp bsadum sbp1grp*bsadum .

*-------------------------------------------------------------Question 10 - Rerun Twoway Anova Without Interaction.
UNIANOVA
  sbp2  BY sbp1grp bsadum
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /SAVE = PRED RESID
  /PLOT = PROFILE( sbp1grp*bsadum )
  /EMMEANS = TABLES(sbp1grp)
  /EMMEANS = TABLES(bsadum)
  /EMMEANS = TABLES(sbp1grp*bsadum)
  /PRINT = DESCRIPTIVE
  /CRITERIA = ALPHA(.05)
  /DESIGN = sbp1grp bsadum .

SAVE OUTFILE='C:\temp\afifi.sav'
  /COMPRESSED.