* ************************************************
* SPSS RUN 4—ONEWAY AND TWOWAY
*                        FACTORIAL ANOVA
*                        LOGISTIC REGRESSION
* *************************************************.
GET FILE='c:\temp\werner.sav'.
FREQUENCIES
  VARIABLES=agegroup  .
*---------------------Compare Means--One-Way Anova.
ONEWAY
  chol BY agegroup
  /POLYNOMIAL= 1
  /STATISTICS DESCRIPTIVES HOMOGENEITY
  /PLOT MEANS
  /MISSING ANALYSIS
  /POSTHOC = TUKEY BONFERRONI ALPHA(.05).

*------------------General Linear Model--Univariate for twoway anova--GLM can also be used for oneway.
UNIANOVA
  chol  BY agegroup pill
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /POSTHOC = agegroup ( TUKEY )
  /PLOT = PROFILE( agegroup*pill )
  /PRINT = DESCRIPTIVE HOMOGENEITY
  /CRITERIA = ALPHA(.05)
  /DESIGN = agegroup pill agegroup*pill .

*-------------------General Linear Model--Include Covariates in Model.
UNIANOVA
  chol  BY agegroup pill  WITH height weight
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /SAVE = PRED SEPRED RESID ZRESID
  /PRINT = DESCRIPTIVE HOMOGENEITY
  /CRITERIA = ALPHA(.05)
  /DESIGN = height weight agegroup pill agegroup*pill .

*------------------Check Residuals for Normality -- Descriptive Statistics---Explore.
EXAMINE
  VARIABLES=zre_1
  /PLOT BOXPLOT STEMLEAF HISTOGRAM NPPLOT
  /COMPARE GROUP
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*-----------------Scatterplot of Residuals vs. Predicted Value.
GRAPH
  /SCATTERPLOT(BIVAR)=pre_1 WITH zre_1
  /MISSING=LISTWISE .

*---------------------------------------------Setup for LOGISTIC REGRESSION.

RECODE
  chol
  (Lowest thru 249=0) (250 thru Highest=1)  INTO hichol .
EXECUTE.
FREQUENCIES
  VARIABLES=hichol  .
CROSSTABS
  /TABLES=agegroup  BY hichol
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ 
  /CELLS= COUNT ROW.

*--------------------------------------Regression--Binary Logistic.
LOGISTIC REGRESSION VAR=hichol
  /METHOD=ENTER acid age alb calcium height weight
  /SAVE PRED
  /CLASSPLOT
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

*-----------------------------------AGE is Categorical.
LOGISTIC REGRESSION VAR=hichol
  /METHOD=ENTER acid alb calcium height weight agegroup
  /CONTRAST (agegroup)=Indicator(1)
  /SAVE PRED
  /CLASSPLOT
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

LOGISTIC REGRESSION VAR=hichol
  /METHOD=FSTEP(LR) acid alb calcium height weight agegroup
  /CONTRAST (agegroup)=Indicator(1)
  /CLASSPLOT
  /PRINT=CI(95)
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

LOGISTIC REGRESSION VAR=hichol
  /METHOD=ENTER age calcium acid
  /SAVE PRED
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .

*---------------------------------------Graphs.
COMPUTE xbeta1 = -15.5828+.0687*age+1.1046*calcium+.3493*acid .
EXECUTE .
GRAPH
  /SCATTERPLOT(BIVAR)=xbeta1 WITH pre_4
  /MISSING=LISTWISE .
COMPUTE logit = ln(pre_4/(1-pre_4)) .
EXECUTE .
GRAPH
  /SCATTERPLOT(BIVAR)=xbeta1 WITH logit
  /MISSING=LISTWISE .