* ****************************************************
* SPSS RUN # 1 -- READING IN RAW DATA
*
*                 SIMPLE DATA DESCRIPTION
*                 SPLIT FILE
*                 BAR CHART
*                 HISTOGRAM
*                 SCATTER PLOT 
*	      PAIRED AND INDEPENDENT SAMPLES T-TEST
*                 SAVE SPSS DATA SET
*
* FILE: EXAMPLE1.SPS
* *****************************************************.

*---------------------------------Read in Data so each pair is an observation--2 records per case.
DATA LIST 
   FILE="c:\temp\labdata\werner2.dat" RECORDS=2
   /ID 1-4 (A) AGE1 5-8 HEIGHT1 9-12 WEIGHT1 13-16 PILL1  20
   CHOL1 21-24 ALB1 25-28 (1) CALCIUM1 29-32 (1) ACID1 33-36 (1) PAIR1 37-39
  / ID2 1-4 (A) AGE2 5-8 HEIGHT2 9-12 WEIGHT2 13-16 PILL2 20 
   CHOL2 21-24 ALB2 25-28 (1) CALCIUM2 29-32 (1) ACID2 33-36 (1) PAIR2 37-39.
EXECUTE.

VALUE LABELS PILL1 PILL2 (1)NOPILL (2)PILL.
MISSING VALUES HEIGHT1, WEIGHT1, HEIGHT2, WEIGHT2 (999).
MISSING VALUES ALB1,CALCIUM1,ACID1, ALB2, CALCIUM2, ACID2 (99).
RECODE CHOL1 CHOL2 (LO THRU 100=SYSMIS) (400 THRU HI=SYSMIS). 
EXECUTE.

LIST VARIABLES=AGE1 HEIGHT1 WEIGHT1 PILL1 AGE2 HEIGHT2 WEIGHT2 PILL2
   /CASES FROM 1 TO 5
   /FORMAT=NUMBERED.

DESCRIPTIVES
  VARIABLES=age1 height1 weight1 pill1 chol1 alb1 calcium1 acid1 pair1 age2
  height2 weight2 pill2 chol2 alb2 calcium2 acid2 pair2
  /STATISTICS=MEAN STDDEV MIN MAX .

FREQUENCIES VARIABLES=WEIGHT1
   /STATISTICS=ALL
   /BARCHART=PERCENT.

FREQUENCIES VARIABLES=HEIGHT1
   /HISTOGRAM=NORMAL
   /PERCENTILES=5,10,25,50,75,90,95.

GRAPH
   /TITLE "SCATTER PLOT OF HEIGHT1 VS WEIGHT1"
   /SCATTERPLOT HEIGHT1 WITH WEIGHT1.
T-TEST
  PAIRS= chol1 alb1 calcium1 acid1  WITH chol2 alb2 calcium2 acid2 (PAIRED)
  /CRITERIA=CIN(.95)
  /MISSING=ANALYSIS.

SAVE OUTFILE="c:\temp\matched.sav".
DISPLAY DICTIONARY.

*-------------------------------Read in Data so each Person is an observation--one record per case.
DATA LIST 
   FILE="c:\temp\labdata\werner2.dat" RECORDS=1
   /ID 1-4 (A) AGE 5-8 HEIGHT 9-12 WEIGHT 13-16 PILL 20
   CHOL 21-24 ALB 25-28 (1) CALCIUM 29-32 (1) ACID 33-36 (1) PAIR 37-39.
EXECUTE.

VARIABLE LABELS AGE "AGE IN YEARS" HEIGHT "HEIGHT IN INCHES" 
   WEIGHT "WEIGHT IN POUNDS" CHOL "CHOLESTEROL LEVEL" ACID "URIC ACID".
VALUE LABELS PILL (1)NOPILL (2)PILL.

MISSING VALUES HEIGHT, WEIGHT (999).
MISSING VALUES ALB,CALCIUM,ACID (99).

RECODE CHOL (LO THRU 100=SYSMIS) (400 THRU HI=SYSMIS). 
EXECUTE.

RECODE
  age
  (Lowest thru 27=1)  (28 thru 39=2)  (40 thru Highest=3)  INTO  agegroup .
EXECUTE .
VALUE LABELS
          AGEGROUP (1) "YOUNG" (2) "MEDIUM" (3) "MATURE".

RECODE
  chol
  (Lowest thru 240=0)  (241 thru Highest=1)  INTO  hichol .
EXECUTE.
VALUE LABELS
           HICHOL (0) "LOW" (1) "HIGH".

CROSSTABS
  /TABLES=agegroup  BY hichol
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ 
  /CELLS= COUNT ROW.

SORT CASES BY PILL.
SPLIT FILE BY PILL.

DESCRIPTIVES
  VARIABLES=age height weight pill chol alb calcium acid pair
  /STATISTICS=MEAN STDDEV MIN MAX .

SPLIT FILE OFF.

GRAPH
   /TITLE "SCATTER PLOT OF HEIGHT VS WEIGHT"
   /SCATTERPLOT HEIGHT WITH WEIGHT BY PILL.

T-TEST
  GROUPS=pill(1 2)
  /MISSING=ANALYSIS
  /VARIABLES=chol alb calcium acid
  /CRITERIA=CIN(.95) .

COMPUTE logwt = ln(weight+1) .
EXECUTE .

FILE LABEL SPSS SYSTEM FILE FOR WERNER DATA.

DOCUMENT THIS FILE CONTAINS INFORMATION ON WOMEN 
  TAKING THE PILL AND THOSE NOT TAKING IT ON 
  CERTAIN BLOOD CHEMISTRY VALUES FOR 94 PAIRS.

DISPLAY DOCUMENT.
DISPLAY DICTIONARY.
SAVE OUTFILE='C:\temp\werner.sav'
   /COMPRESSED.