* Author: William D. MacMillan
* Prepared for ICPSR time-series and cross-section data analysis
* 5/20/09
use http://www-personal.umich.edu/~franzese/ICPSR/garmit_esspanel1.dta, clear
drop if cc == 13
local model spend unem growthpc depratio left cdem trade lowwage fdi
local rhs unem growthpc depratio left cdem trade lowwage fdi
local effecttype fe be re 

* the basic fe model
xi: reg `model' i.cc
more

testparm _I*
more

* constructing the variables for the within differenced model
foreach var of local model {
	qui gen `var'diff = .
	forvalues i = 1/18 {
		qui sum `var' if cc == `i'
		qui replace `var'diff = `var'-r(mean) if cc == `i'
	}
}

reg spenddiff unemdiff growthpcdiff depratiodiff leftdiff cdemdiff tradediff lowwagediff fdidiff
more

matrix bvec=e(b)
scalar bunemdiff = bvec[1,1]
gen b_unem_diff = bunemdiff*unem


forvalues i = 2/3 {
reg `model' if cc == `i'
more
}

foreach var of local rhs {
	qui gen `var'inter_I3 = `var'*_Icc_3
}

reg spend `rhs' *inter_I3 _Icc_3  if (cc==2)|(cc==3)
more

reg spend unem skand skand_unem, cluster(cc)
more

xtreg spend unem skand skand_unem
more

xttest0
more

foreach type of local effecttype {
	xtreg `model', `type' i(cc)
	more
	matrix b`type'vec = e(b)
	scalar b`type' = b`type'vec[1,1]
	gen b_unem_`type' = b`type'*unem
}

sort unem

graph twoway 	(scatter spend unem, msymbol(circle_hollow) mcolor(black) msize(medium)) ///
      			(line b_unem_be unem, clwidth(medium) clcolor(blue)lpattern(solid)) ///
        	 	(line b_unem_re unem, clwidth(medium) clcolor(red)lpattern(solid)) ///
				(line b_unem_diff unem, clwidth(medium) clcolor(black)lpattern(solid)) ///
				(line b_unem_fe unem, clwidth(medium) clcolor(green) lpattern(solid)), ///
		 		ytitle(, size(3)) scheme(s2mono) graphregion(fcolor(white))